0
$\begingroup$

maybe the Pythagorean equation is not alone. can't this equation be just one element of an array like this for example. exponents must be prime numbers (otherwise it's just a combination of other elements)

first elment a^2+b^2=c^2 (this is Pythagoras) second element a^3+b^3+c^3=d^3 ( but I can't visualize it in the coordinate system like Pythagoras equation) thirth element a^5+b^5+c^5+d^5+e^5=f^5 fourth element a^7+b^7+c^7...et

$\endgroup$
1
  • $\begingroup$ Yes there are integers with: n=3. The smallest are: 3^3+ 4^3+ 5^3==6^3; They are called "Fermat cubics". There are also solutions for n=4,5,6,... $\endgroup$ Jan 9 at 10:55

1 Answer 1

2
$\begingroup$
Clear["Global`*"]

To bound the problem let 1 <= {a, b, c} <= 100 and to avoid equivalent results that are just reorderings of {a, b, c} let {a, b, c} be ordered such that a <= b <= c <= 100,

(inst = Select[
    Flatten[
     Table[{a, b, c, Norm[{a, b, c}, 3]},
      {a, 1, 100}, {b, a, 100}, {c, b, 100}],
     2],
    IntegerQ@Last@# &]) // Length

(* 98 *)

Verifying,

And @@ (Total[Most[#]^3] == Last[#]^3 & /@ inst)

(* True *)

Looking at the first five and last five instances,

TableForm[inst[[{1, 2, 3, 4, 5, 94, 95, 96, 97, 98}]], 
 TableHeadings -> {None, {a, b, c, d}},
 TableAlignments -> {Right, Center}]

enter image description here

{dmin, dmax} = MinMax[inst[[All, 4]]]

(* {6, 139} *)

Plotting,

Legended[
 ListPointPlot3D[Most /@ inst,
  AxesLabel -> (Style[#, 14] & /@ {a, b, c}),
  ColorFunction -> Function[{a, b, c},
    ColorData["Rainbow"][
     Rescale[Norm[{a, b, c}, 3],
      {dmin, dmax}]]],
  ColorFunctionScaling -> False],
 BarLegend[{"Rainbow", {dmin, dmax}},
  LegendLabel -> Style[d, 14]]]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.