An asymptotic expansion for MeijerG function

By using Mathematica

Series[MeijerG[{{-(1/2)}, {}}, {{-(1/2), -(1/2), 1/2}, {}}, a x], {x,0, 0}, Assumptions -> a > 0],

I got an asymptotic expansion of MeijerG function at $$x\approx 0$$ for $$a>0$$ as $$G_{1,3}^{3,1}\left(a x\left| \begin{array}{c} -\frac{1}{2} \\ -\frac{1}{2},-\frac{1}{2},\frac{1}{2} \\ \end{array} \right.\right)\xrightarrow{} \frac{-\log (a)-\log (x)-2 \gamma }{\sqrt{a} \sqrt{x}}+O\left(\sqrt{x}\right).$$

However, with available asymptotic expression in MeijerG, I could not derive above expression.

Does anyone have an idea of deriving this?

Here is the plot:

• Is the MA result correct? Dec 29, 2019 at 15:48
• I added an example plot.
– Frey
Dec 29, 2019 at 16:10
• You may reduce the MeierGto simpler functions. Have a look here Bateman, H.; Erdélyi, A. (1953). Higher Transcendental Functions, Vol. I (PDF). New York: McGraw–Hill. (see § 5.3, "Definition of the G-Function", Eq.(32) on p. 218) Dec 29, 2019 at 18:42

We can roundtrip your expression by first finding the MellinTransform and then instead of applying InverseMellinTransform, we can just take the first residue. This ends up giving the main series term. [formula]

Here's the Mellin transform:

mei = MeijerG[{{-(1/2)}, {}}, {{-(1/2), -(1/2), 1/2}, {}}, a x];

mel = MellinTransform[mei, x, s]


$$-\frac{1}{2} \pi (2 s-1) a^{-s} \sec (\pi s) \Gamma \left(s-\frac{1}{2}\right)^2$$

Now in order to find where to take the residue, we need to know the strip in which this transform exists:

MellinTransform[mei, x, s, GenerateConditions -> True]

ConditionalExpression[..., 1/2 < Re[s] < 3/2]


It turns out summing residues in the complex plane to the right of the strip will diverge and so we sum to the left. This means we'll start with s == 1/2:

Residue[mel x^-s, {s, 1/2}]


$$\displaystyle \frac{-2\gamma - \log(a) - \log(x)}{\sqrt{a} \sqrt{x}}$$

• Clear explanation! Thanks @Chip Hurst.
– Frey
Dec 30, 2019 at 12:56