2
$\begingroup$

I'm attempting to solve the following problem.

Consider the permutation group $G=\langle\rho,\sigma\rangle\leq S_{14}$ where $\rho=(1,3,5,7,9,11,13)(2,4,6,8,10,12,14)$ and $\sigma=(1,2)(3,6)(4,5)(7,8)(9,12)(10,13)(11,14)$. Determine $|G|$ and find a presentation of $G$ with two generators and as few relations as possible, such that $\rho$ and $\sigma$ satisfy the relations you have chosen.

I'm looking for a good way to do this by hand, but all the methods I know of are inefficient. Even computationally, I'm still struggling with the second part. $|G|=336=2^4\cdot3\cdot7$, so I need elements of order $2$, $3$, and $7$ to define the relations. It's easily verified that $|\rho|=7$ and $|\sigma|=2$, but finding the right element of order $3$ that is some combination of $\rho$ and $\sigma$ is a challenge. For example, $\rho^3(\sigma\rho^3)^2$ is of order $3$, but the group $\langle a,b:a^7=b^2=a^3(ab^3)^2=1\rangle$ has order $2$. My Sage code is listed below. I'm open to using pretty much any language if someone has an idea (I have experience with Maple, Mathematica, and Matlab, but would be willing to try Magma, GAP, or otherwise).

sage: G = SymmetricGroup(14)
sage: rho = G([(1,3,5,7,9,11,13),(2,4,6,8,10,12,14)])
sage: sigma = G("(1,2),(3,6),(4,5),(7,8),(9,12),(10,13),(11,14)")
sage: H=G.subgroup([sigma,rho])
sage: order(H)
sage: order(rho^3*(sigma*rho^3)^2)
336
3
sage: F.<a,b> = FreeGroup()
sage: G = F / [a^7, b^2, a^3*(a*b^3)^2]
sage: G
sage: order(G)
Finitely presented group < a, b | a^7, b^2, a^3*(a*b^3)^2 >
2
$\endgroup$
  • 1
    $\begingroup$ It should be $(a^3(ab^3)^2)^3=1$ if you want it to be of order $3$. $\endgroup$ – Matt Samuel Nov 8 at 16:45
  • $\begingroup$ @MattSamuel Ah, true! This unfortunately doesn't give a group of the right order (in fact memory runs out before the order is computed). Guess I'll keep playing around with different elements of these orders. $\endgroup$ – Atsina Nov 8 at 17:46
  • $\begingroup$ @Atsina if memory runs out, that's likely an indicator that the group is infinite. Check relations in this case. $\endgroup$ – Alexander Konovalov Nov 8 at 20:17
  • $\begingroup$ @AlexanderKonovalov True, but it's not the case that any $x^2=y^3=z^7=1$ will work as relations. The challenge is finding ones that do generate a group of order $336$ AND are satisfied by $\rho$ and $\sigma$. $\endgroup$ – Atsina Nov 8 at 21:03
2
$\begingroup$

This is an attempt of a solution in GAP. First, permutation group:

gap> rho:=(1,3,5,7,9,11,13)(2,4,6,8,10,12,14);
(1,3,5,7,9,11,13)(2,4,6,8,10,12,14)
gap> sigma:=(1,2)(3,6)(4,5)(7,8)(9,12)(10,13)(11,14);
(1,2)(3,6)(4,5)(7,8)(9,12)(10,13)(11,14)
gap> G:=Group(rho,sigma);
Group([ (1,3,5,7,9,11,13)(2,4,6,8,10,12,14), (1,2)(3,6)(4,5)(7,8)(9,12)(10,13)
(11,14) ])

Now convert the group into an isomorphic fp group:

gap> phi:=IsomorphismFpGroup(G);
[ (1,2)(3,6)(4,5)(7,8)(9,12)(10,13)(11,14), (1,3)(4,14)(5,9)(6,8), 
  (2,14,6)(3,13,5)(7,11,9)(8,12,10) ] -> [ F1, F2, F3 ]
gap> H:=Image(phi);
<fp group on the generators [ F1, F2, F3 ]>

This group is given by 3 generators and the following relations:

gap> RelatorsOfFpGroup(H);
[ F1^2, 
  F1^-1*F2*F1*F2*F3*F2*F3^-1*(F2*F3)^4*F2*F3^-1*F2^-1*F3^2*(F2*F3^-1)^2*F2*F3*\
F2^-1*F3^-1*F2^-1, F1^-1*F3*F1*(F3*F2^-1)^2*F3^-1, F2^2, F3^3, (F2*F3)^7, 
  (F2^-1*F3^-1*F2*F3)^4 ]

and rho and sigma correspond to the following elements of H:

gap> Image(phi,rho);
(F2*F3^-1)^2*(F2*F3)^3*F2*F3^-1*F2^-1*F3^2*(F2*F3^-1)^2*F2*F3*F2^-1*F3^-1*F2^-\
1
gap> Image(phi,sigma);
F1

This group can be given as 2-generated:

gap> tau:=IsomorphismSimplifiedFpGroup(H);
[ F1, F2, F3 ] -> [ F1, F3*(F1*F3*F1*F3^-1)^2*F1*F3*F1, F3 ]
gap> T:=Image(tau);
<fp group on the generators [ F1, F3 ]>
gap> RelatorsOfFpGroup(T);
[ F1^2, F3^3, (F1*F3^-1)^8, F1*F3*F1*F3^-1*(F1*F3)^2*(F1*F3^-1)^2*(F1*F3^-1*(F1*F3)^2)^2, 
(F1*F3^-1*F1*F3)^7 ]

and the images of rho and sigma in T are:

gap> (sigma^phi)^tau;
F1
gap> (rho^phi)^tau;
F3*((F1*F3*F1*F3^-1)^2*F1*F3*F1)^2*((F1*F3*F1*F3^-1)^2*F1*F3*F1*F3^2)^3*(F1*F3*F1*F3^-1)^3*(F1^-1*F3^\
-1*F1^-1*F3)^3*F3*((F1*F3*F1*F3^-1)^2*F1*F3*F1)^3*(F3*F1^-1*F3^-1*F1^-1)^3*F3^-2*(F1^-1*F3^-1*F1^-1*F\
3)^2*(F1^-1*F3^-1)^2

That's quite unreadable, but using SetReducedMultiplication one could force immediate reduction when multiplying, keeping words short at extra cost per multiplication:

gap> SetReducedMultiplication(T);
gap> s:=(sigma^phi)^tau;
F1
gap> r:=(rho^phi)^tau;
(F1*F3^-1)^3*F1*F3

This is still not what you may want, though, as you're interested in relations which are satisfied by s and r, but hopefully simple enough to continue from here.

P.S. You can also check that all three groups are indeed isomorphic:

gap> List([G,H,T],IdGroup);
[ [ 336, 208 ], [ 336, 208 ], [ 336, 208 ] ]
$\endgroup$
4
$\begingroup$

$\langle x,y \mid x^7,y^2,(xyx^{-1}yx)^2,(xyx^{-3}yx^2)^2 \rangle$ is a presentation on the two given generators.

Or better, $\langle x,y \mid y^2,(xyx^{-1}yx)^2,x^7(xyx^{-3}yx^2)^2 \rangle$ is a presentation and three really is the smallest possible number of relators.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.