3
$\begingroup$

Let $r$, $A$, $A_0$,$A_1$ and $A_2$ be real numbers.

By generalizing the approach given in my answer to How can I solve the following higher order ODE? I have found the following.

Define the following functions : \begin{eqnarray} a_2(x) &:=& 4 A^2 A_0 r^2 x^{2 r-2}&+4 A A_1 r^2 x^{r-2}&+\frac{(4 A_2-1) r^2+1}{x^2}\\ a_3(x) &:=& 12 A^2 A_0 (r-1) r^2 x^{2 r-3}&+6 A A_1 (r-2) r^2 x^{r-3}&+\frac{3 \left((1-4 A_2) r^2-1\right)}{x^3}\\ a_4(x)&:=&4 A^2 A_0 (r-1) r^2 (2 r-3) x^{2 r-4}&+2 AA_1 (r-3) (r-2) r^2 x^{r-4}&+\frac{3 (4 A_2-1) r^2+3}{x^4} \end{eqnarray} Now consider a following fourth order Ordinary Differential Equation (ODE): \begin{equation} \frac{d^4 v(x)}{d x^4} + a_2(x) \frac{d^2 v(x)}{d x^2} + a_3(x) \frac{d^1 v(x)}{d x^1} + a_4(x) v(x)=0 \end{equation}

Then the solution to the ODE above reads: \begin{equation} v(x)= C_1 v_1(x)^2 + C_2 v_2(x)^2 + C_{1,2} v_1(x) v_2(x) \end{equation} where \begin{equation} v_{1,2}(x) := x^{\frac{1-r}{2}} \cdot y_{1,2}(A x^r) \end{equation} and \begin{eqnarray} y_1(x) &=& M_{-\frac{\imath A_1}{2\sqrt{A_0}},-\frac{\imath}{2} \sqrt{-1+4 A_2}}(2\imath \sqrt{A_0} x)\\ y_2(x) &=& W_{-\frac{\imath A_1}{2\sqrt{A_0}},-\frac{\imath}{2} \sqrt{-1+4 A_2}}(2\imath \sqrt{A_0} x) \end{eqnarray} where $M_{\cdot,\cdot}(x)$ and $W_{\cdot,\cdot}(x)$ are Whittaker functions https://en.wikipedia.org/wiki/Whittaker_function .

The code snippet below provides a verification:

In[970]:= r =.; A =.; A0 =.; A1 =.; A2 =.;
{a2[x_], a3[x_], 
   a4[x_]} = {(1 + (-1 + 4 A2) r^2)/x^2 + 4 A A1 r^2 x^(-2 + r) + 
    4 A^2 A0 r^2 x^(-2 + 2 r), (3 (-1 + (1 - 4 A2) r^2))/x^3 + 
    6 A A1 (-2 + r) r^2 x^(-3 + r) + 
    12 A^2 A0 (-1 + r) r^2 x^(-3 + 2 r), (3 + 3 (-1 + 4 A2) r^2)/
    x^4 + 2 A A1 r^2 (-3 + r) (-2 + r) x^(-4 + r) + 
    4 A^2 A0 r^2 (-1 + r) (-3 + 2 r) x^(-4 + 2 r)};
y1[x_] = WhittakerM[-((I A1)/(2 Sqrt[A0])), -(1/2) I Sqrt[-1 + 4 A2], 
   2 I Sqrt[A0] x];
y2[x_] = WhittakerW[-((I A1)/(2 Sqrt[A0])), -(1/2) I Sqrt[-1 + 4 A2], 
   2 I Sqrt[A0] x];
v1[x_] = x^((1 - r)/2) y1[A x^r];
v2[x_] = x^((1 - r)/2) y2[A x^r];
FullSimplify[(D[#, {x, 4}] + a2[x] D[#, {x, 2}] + a3[x] D[#, {x, 1}] +
      a4[x] #) & /@ {v1[x]^2, v2[x]^2, v1[x] v2[x]}]

Out[976]= {0, 0, 0}

Now what we have done in here is the following. We rescaled the abscissa and the ordinates of Whittaker functions and then constructed a symmetric product of those functions, which in turn satisfies a forth order ODE. This procedure follows pretty much the ideas from [1].

Update: Here is another example of a 4th order linear ODE that has a solution in terms of a symmetric product of solutions to 2nd order ODEs. Let $n$, $w$ and $A$ be parameters. Now consider a following ODE: \begin{eqnarray} y^{(4)}(x) + \frac{w}{x^2} y^{(2)}(x) + \frac{-8 (n+6) w-5 n (n+2) (n+4)}{16 x^3} y^{(1)}(x) + \left( 4 A x^{2 n}-\frac{3 \left(n^2-16\right) \left(7 n^2+16 n+16 w\right)}{256 x^4}\right) y(x)=0 \end{eqnarray}

The fundamental set of solutions to this ODE is given by $\left\{ y_{1,\eta_1}(x) \cdot y_{2,\eta_2}(x)\right\}$ for $\eta_1=-1,1$ and $\eta_2=-1,1$ where: \begin{eqnarray} y_{1,\eta}(x)&:=& x^{\frac{1}{2}-\frac{n}{8}} \cdot J_{\eta \frac{\sqrt{-3 n^2-12 n-8 w+8}}{2 \sqrt{2} \sqrt{(n+2)^2}}}(\frac{2 \sqrt[4]{A}}{\sqrt{n^2+4 n+4}}\cdot x^{\frac{n}{2}+1})\\ y_{2,\eta}(x)&:=& x^{\frac{1}{2}-\frac{n}{8}} \cdot J_{\eta \frac{\sqrt{-3 n^2-12 n-8 w+8}}{2 \sqrt{2} \sqrt{(n+2)^2}}}(\frac{2 \sqrt[4]{A} \imath}{\sqrt{n^2+4 n+4}}\cdot x^{\frac{n}{2}+1}) \end{eqnarray}

In[790]:= n =.; w =.; A =.; Clear[y1]; Clear[y2]; x =.; eX =.;
y1[eta_, x_] = 
  x^(1/2 - n/8) BesselJ[
    eta Sqrt[8 - 12 n - 3 n^2 - 8 w]/(2 Sqrt[2] Sqrt[(2 + n)^2]), (
     2 A^(1/4) Sqrt[1])/Sqrt[4 + 4 n + n^2] x^(n/2 + 1)];
y2[eta_, x_] = 
  x^(1/2 - n/8) BesselJ[
    eta Sqrt[8 - 12 n - 3 n^2 - 8 w]/(2 Sqrt[2] Sqrt[(2 + n)^2]), (
     2 A^(1/4) Sqrt[-1])/Sqrt[4 + 4 n + n^2] x^(n/2 + 1)];

eX = ((-((3 (-16 + n^2) (16 n + 7 n^2 + 16 w))/(256 x^4)) + 
         4 A x^(2 n)) # + (-5 n (2 + n) (4 + n) - 8 (6 + n) w) /(
       16 x^3) D[#, x] + w /x^2 D[#, {x, 2}] + D[#, {x, 4}]) & /@ {y1[
      1, x] y2[1, x], y1[-1, x] y2[1, x], y1[1, x] y2[-1, x], 
    y1[-1, x] y2[-1, x]};
{n, w, A} = RandomReal[{0, 10}, 3, WorkingPrecision -> 50];
x = RandomReal[{0, 1}, WorkingPrecision -> 50];
eX


Out[796]= {0.*10^-43 + 0.*10^-43 I, 0.*10^-43 + 0.*10^-43 I, 
 0.*10^-43 + 0.*10^-43 I, 0.*10^-43 + 0.*10^-43 I}

Now my question would be the following . Can we construct solutions of any forth order ODE with "polynomial" coefficients in the way we did this in here? For example can we solve the ODE given in here How can I solve the following higher order ODE? with this method?If yes what other second order ODEs -- rather than the Whittaker ODE --could we be using for that purpose.

[1]M.F. Singer, Solving Homogeneous Linear Differential Equations in Terms of Second Order Linear Differential Equations, Am. J. of Math., 107, 1985, 663-696.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Browse other questions tagged or ask your own question.