It can be shown that the partial sums have an asymptotic expansion of the form
$$
\sum_{k=1}^n\int_k^{k+1}\cdots\,du \approx c_0 + \frac{c_1}{n} + \frac{c_2}{n^2} + \cdots, \tag{$*$}
$$
where
$$
c_0 := \sum_{k=1}^\infty\int_k^{k+1}\cdots\,du.
$$
This tells us that the convergence of the partial sums to $c_0$ is very slow; to naively compute $10$ digits of $c_0$ we might need to evaluate something like the $10^{10}\text{th}$ partial sum, which is just not feasible.
We can instead try some sort of convergence acceleration. Sequences with this kind of asymptotic expansion are often well-suited to Richardson extrapolation, and it ends up working pretty well here.
Using Mathematica we can calculate the first $50$ partial sums to roughly $100$ digits relatively quickly with the command
a[k_] := a[k] =
NIntegrate[
Gamma[-k + u + 1]/(Gamma[1 + 1/u] Gamma[-k + u + 1 - 1/u] u^2), {u, k, k + 1},
WorkingPrecision -> 100];
Subscript[T, 0] = Table[Sum[a[k], {k, 1, n}], {n, 1, 50}];
Now $T_0$ is a list containing the numerical values of the first $50$ partial sums. We then iteratively compute lists $T_1, T_2, \ldots, T_{49}$, each of which is an accelerated version of the previous one, using the formula
$$
T_{k+1}(n) := \frac{x_n T_k(n+1) - x_{n+k+1}T_k(n)}{x_n - x_{n+k+1}} \qquad (1 \leq n \leq 50 - k - 1),
$$
where $x_j$ is a sequence of constants. Because the asymptotic expansion $(*)$ involves only powers of $n$, we take $x_j = 1/j$.
The Mathematica code is
x[j_] := 1/j;
For[k = 0, k <= Length[Subscript[T, 0]] - 2, k++,
Subscript[T, k + 1] =
Table[(x[j] Subscript[T, k][[j + 1]] -
x[j + k + 1] Subscript[T, k][[j]])/(x[j] - x[j + k + 1]),
{j, 1, Length[Subscript[T, 0]] - k - 1}]
]
The content of the last three lists is now
T_47 = {0.82738000080545448263010087550271301001436936357076159313066822525902388323,
0.82738000080545448263010087550271301001436952134826362854767855646955812112,
0.8273800008054544826301008755027130100143695297480234033866397050979721660}
T_48 = {0.82738000080545448263010087550271301001436952463529492095219960503644425107,
0.8273800008054544826301008755027130100143695300980133940049297529574894179}
T_49 = {0.8273800008054544826301008755027130100143695302094974444753936335273066662}
Based on these computations, I suggest that
$$
\int_{0}^1\binom{ \left\{ \frac{1}{z} \right\}}{z}dz \doteq 0.82738\ 00008\ 05454\ 48263\ 01008\ 75502\ 71301\ 00143\ 69530.
$$
I learned this version of the Richardson extrapolation from section 1.5 of the book Scientific Computation on Mathematical Problems and Conjectures by Richard S. Varga.
https://epubs.siam.org/doi/book/10.1137/1.9781611970111