2
$\begingroup$

Let $ABC$ be a triangle, and $P,Q$ two inverse points with respect to its circumcircle. Let the circle through $A,P,Q$ meet $AB,AC$ at $A_c,A_b$ respectively. Analogously define $B_a,B_c,C_a,C_b$. Let $A_1$ be the intersection of $B_cB_a$ and $C_aC_b$. Analogously define $B_1,C_1$. Prove that the circles on diameters $\overline{AA_1},\overline{BB_1},\overline{CC_1}$ concur on $(ABC)$.

Figure

Here is some progress so far:

Let $D=BC\cap A_bA_c$. Now $(ABC),(APQ)$ are orthogonal since $OA^2=OP\cdot OQ$. Consider the spiral similarity $\overline{A_bA_c}\to\overline{CB}$. From the orthogonality of $(ABC),(APQ)$, it follows that $A_bA_c\perp BC$, with similar results for other vertices.

Let $E=CA\cap B_cB_a, F=AB\cap C_aC_b$. Note that the circles on diameters $\overline{AA_1},\overline{BB_1},\overline{CC_1}$ are precisely the Miquel circles of $DEF$ wrt $\triangle ABC$. Thus it suffices to show that $D,E,F$ are collinear.

$\endgroup$
4
$\begingroup$

This is an algebraic proof using polynomial computations. What I like to think of as the “don't make me think” approach. As such it's pretty far away from what you already have. But seeing that there was no other answer in the past two days, I reckon that this proof is better than none, and that bumping the question may do more good than having it marked as answered will do bad.

Choosing coordinates

I'm using homogeneous coordinates. Without loss of generality one can choose the defining points of the configuration like this:

$$ A=\begin{pmatrix}1-a^2\\2a\\1+a^2\end{pmatrix}\quad B=\begin{pmatrix}1-b^2\\2b\\1+b^2\end{pmatrix}\quad C=\begin{pmatrix}1-c^2\\2c\\1+c^2\end{pmatrix}\qquad P=\begin{pmatrix}p\\0\\1\end{pmatrix}\quad Q=\begin{pmatrix}1\\0\\p\end{pmatrix} $$

This is without loss of generality because one may always choose the coordinate system in such a way that the circumcircle is the unit circle. (The special case where $A,B,C$ are collinear is already too degenerate since it will make large parts of the construction undefined.) One can furthermore rotate the coordinate system such that $P$ and $Q$ lie on the $y=0$ axis. I'm using the tangent half-angle substitution for $A,B,C$ which can describe any point on the unit circle except for $(-1,0)$ (which corresponds to an infinite parameter). If one of these three points is $(-1,0)$, then one can rotate the whole setup by $180°$. If this still leaves one point at $(-1,0)$ then this means that $P,Q$ and two of $A,B,C$ are collinear, which again makes large parts of the construction undefined. So without loss of generality the above coordinates can represent any sufficiently non-degenerate situation (as well as several which are still too degenerate for this construction).

Formulating the computation

Next we need circles through $P$ and $Q$. Two such circles are defined by

$$ R_1=\begin{pmatrix} -2p & 0 & 1+p^2 \\ 0 & -2p & 0 \\ 1+p^2 & 0 & -2p \end{pmatrix} \qquad R_2=\begin{pmatrix} 0 & 0 & 0 \\ 0 & 0 & 1 \\ 0 & 1 & 0 \end{pmatrix} $$

$R_1$ is the circle with diameter $PQ$, while $R_2$ is the degenerate circle consisting of the line $y=0$ and the line at infinity (i.e. $z=0$). Any other circle through $P$ and $Q$ is a linear combination of these two. So you get

$$\bigcirc APQ=(A^T\cdot R_1\cdot A)R_2 - (A^T\cdot R_2\cdot A)R_1$$

Likewise for $\bigcirc BPQ$ and $\bigcirc CPQ$. Any point on the line $b$ can be described as a linear combination of $A$ and $C$. The point $A_b$ in particular can be described as

$$ A_b = (C^T\cdot\bigcirc APQ\cdot C)A - 2(A^T\cdot\bigcirc APQ\cdot C)C $$

Likewise for $A_c,B_a,B_c,C_a,C_b$. Joining points and intersecting lines can both be computed via the cross product, so you have

$$A_1 = (B_c\times B_a)\times(C_a\times C_b)$$

Likewise for $B_1$ and $C_1$. Next we need a more generic formula for “circle for given diameter“. For points with homogeneous coordinates $(x_1,y_1,z_1)^T$ and $(x_2,y_2,z_2)^T$ this circle is

$$\begin{pmatrix} 2z_1z_2 & 0 & -x_1z_2-z_1x_2 \\ 0 & 2z_1z_2 & -y_1z_2-z_1y_2 \\ -x_1z_2+z_1x_2 & -y_1z_2+z_1y_2 & 2x_1x_2+2y_1y_2 \end{pmatrix}$$

The radical axis of this circle with the unit circle $\bigcirc ABC$ is

$$\begin{pmatrix} z_1x_2 + x_1z_2 \\ z_1y_2 + y_1z_2 \\ -x_1x_2-y_1y_2-z_1z_2 \end{pmatrix}$$

Plugging $A$ and $A_1$ into this formula, one obtains a vector describing the line $AX$, where $X$ is at this point defined as the intersection of $\bigcirc AA_1$ and $\bigcirc ABC$. Likewise for the other two such lines. To show that all three lines concur, verify that their determinant is zero. To show that the common point lies on the unit circle, e.g. intersect two of them (using the cross product) and plug the result into the equation of the unit circle.

Executing the computation

The results of the computation will get fairly large. But they can be kept to a manageable size by canceling common factors after each operation. This is valid because scalar multiples are identified for homogeneous coordinates. If combination of parameters can make that common factor equal to zero, then canceling it would correspond to removing a removable singularity. I'm only printing on example for each group of objects, where the others can be obtained simply by replacing variables.

\begin{align*} \bigcirc APQ&=\begin{pmatrix} 4ap & 0 & -2ap^2-2a \\ 0 & 4ap & -a^2p^2-2a^2p-a^2+p^2-2p+1 \\ -2ap^2-2a & -a^2p^2-2a^2p-a^2+p^2-2p+1 & 4ap \end{pmatrix} \\ A_b&=\begin{pmatrix} a^2cp^2+ac^2p^2+2a^2cp+a^2c+ac^2+ap^2+cp^2-2cp+a+c \\ a^2c^2p^2+2a^2c^2p+a^2c^2-p^2+2p-1 \\ 2ac^2p+2ap \end{pmatrix} \\ A_1&=\begin{pmatrix} a^2b^2c^2p^2+2a^2b^2c^2p+a^2b^2c^2+a^2bcp^2+a^2bc+bcp^2+bc+p^2-2p+1 \\ -ab^2c^2p^2-2ab^2c^2p-ab^2c^2+ap^2-2ap+a \\ 2a^2bcp+2bcp \end{pmatrix} \\ AX&=\begin{pmatrix} a^2bc + 1 \\ -abc + a \\ a^2bc - 1 \end{pmatrix} \\ X&=\begin{pmatrix} 1-(abc)^2 \\ -2abc \\ 1+(abc)^2 \end{pmatrix} \end{align*}

Observations

It may be interesting to note that $X$, the point where the circles intersect, does not depend on $p$. Which means the position of the axis $PQ$ is relevant to the location of $X$, but the position of $P$ and $Q$ on that axis is not. The coordinates of $X$ again follow the form of a tangent half-angle substitution, this time with the parameter $-abc$. Not sure whether any of this can be of use for a different approach at proving this.

Sage code

I did all of the above using Sage.

def simpl(x):
    if x.is_zero(): return x
    return x.parent()(x / gcd(x.list()))
PR1.<a,b,c,p> = ZZ[]
A = vector([1-a^2, 2*a, 1+a^2])
B = A(a=b)
C = A(a=c)
P = vector([p, 0, 1])
Q = vector([1, 0, p])
R1 = matrix(PR1, [[-2*p, 0, p^2+1], [0, -2*p, 0], [p^2+1, 0, -2*p]])
R2 = matrix(PR1, [[0, 0, 0], [0, 0, 1], [0, 1, 0]])
APQ = simpl(A*R1*A*R2 - A*R2*A*R1)
BPQ = APQ(a=b)
CPQ = APQ(a=c)
Ab = simpl(C*APQ*C*A - 2*A*APQ*C*C)
Ac = Ab(a=a, b=c, c=b)
Ba = Ab(a=b, b=a, c=c)
Bc = Ab(a=b, b=c, c=a)
Ca = Ab(a=c, b=a, c=b)
Cb = Ab(a=c, b=b, c=a)
AA = simpl(Ab.cross_product(Ac))
BB = simpl(Bc.cross_product(Ba))
CC = simpl(Ca.cross_product(Cb))
A1 = simpl(BB.cross_product(CC))
B1 = simpl(CC.cross_product(AA))
C1 = simpl(AA.cross_product(BB))
def Radl(P1, P2):
    x1, y1, z1 = P1
    x2, y2, z2 = P2
    v = (z1*x2 + x1*z2, z1*y2 + y1*z2, -x1*x2 - y1*y2 - z1*z2)
    return simpl(P1.parent()(v))
AX = Radl(A, A1)
BX = Radl(B, B1)
CX = Radl(C, C1)
assert matrix((AX, BX, CX)).det().is_zero()
X = simpl(AX.cross_product(BX))
assert (X*diagonal_matrix((1, 1, -1))*X).is_zero()
$\endgroup$
  • $\begingroup$ How can you get R1 in "Formulating the computation"? $\endgroup$ – Zack Ni May 30 '16 at 10:58
  • 1
    $\begingroup$ @ZackNi: Consider a circle with center $(x,y)/z$ and equation $$r^2=(X-x/z)^2+(Y-y/z)^2=X^2-2Xx/z+x^2/z^2+Y^2-2Yy/z+y^2/z^2$$ corresponding to $$(X,Y,1)\cdot \begin{pmatrix}-z&0&x\\0&-z&y\\x&y&zr^2-(x^2+y^2)/z\end{pmatrix}\cdot \begin{pmatrix}X\\Y\\1\end{pmatrix}=0$$ Now in this specific case the center has homogeneous coordinates $(x,y,z)=(1+p^2,0,2p)$ (scale $P$ and $Q$ to same $z$ then add). I fact I wrote the matrix without its lower right entry, and then computed that such that $P$ satisfies the equation. That way I didn't have to compute the radius (or its square) explicitely. $\endgroup$ – MvG May 30 '16 at 11:22

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.