3
$\begingroup$

1-Let $ABC$ and $A'B'C'$ be two triangle inscribed a conic. Let $P$ be a point on the conic. $PA$ meets $B'C'$ at $A_1$, define $B_1, C_1$ cyclically. $PA'$ meets $BC$ at $A'_1$ define $B'_1, C'_1$ cyclically. Then show that six points $A_1, B_1, C_1, A'_1, B'_1, C'_1$ lie on a conic.

First new conic

2-Let $ABC$ and $A'B'C'$ be two triangle inscribed a conic. Let $P$ be a point on the conic. $PA$ meets $BC$ at $A_1$, define $B_1, C_1$ cyclically. $PA'$ meets $B'C'$ at $A'_1$ define $B'_1, C'_1$ cyclically. Then show that six points $A_1, B_1, C_1, A'_1, B'_1, C'_1$ lie on a conic.

Second new conic

$\endgroup$
1
$\begingroup$

This is a proof by homogeneous coordinates, projective geometry and computer algebra.

I start with the first case. First off, observe that your whole setup is invariant under projective transformations. So without loss of generality you may assume that the original conic is the unit circle, and you may further assume that $P$ is at position $[1:0:1]$. Then you can use the tangent half-angle substitution and characterize all the other points as some $[t^2-1:2t:t^2+1]$, assumig that they are distinct from $P$.

Since I don't like using primes in computer algebra input, I'll switch notation: Your $A,B,C$ are my $A_1,B_1,C_1$, your $A',B',C'$ my $A_2,B_2,C_2$, your $A_1,B_1,C_1$ my $A_3,B_3,C_3$ and your $A_1',B_1',C_1'$ my $A_4,B_4,C_4$. So what I computed is this, using Sage:

PR1.<a1,b1,c1,a2,b2,c2> = QQ[]
P = vector([1, 0, 1])
A1 = vector([a1^2-1, 2*a1, a1^2+1])
B1 = A1(a1=b1)
C1 = A1(a1=c1)
A2 = A1(a1=a2)
B2 = A1(a1=b2)
C2 = A1(a1=c2)
def cp(a, b): return a.cross_product(b)
A3 = cp(cp(P, A1), cp(B2, C2))
B3 = cp(cp(P, B1), cp(C2, A2))
C3 = cp(cp(P, C1), cp(A2, B2))
A4 = cp(cp(P, A2), cp(B1, C1))
B4 = cp(cp(P, B2), cp(C1, A1))
C4 = cp(cp(P, C2), cp(A1, B1))
def det3(a, b, c): return matrix([a, b, c]).det()
P1, P2, P3, P4, P5, P6 = (A3, B3, C3, A4, B4, C4)
(det3(P1,P3,P5)*det3(P2,P4,P5)*det3(P1,P4,P6)*det3(P2,P3,P6) -
 det3(P1,P3,P6)*det3(P2,P4,P6)*det3(P1,P4,P5)*det3(P2,P3,P5))

I'm working in a polynomial ring over $\mathbb Q$ with six indeterminates. Each of those takes the role of $t$ above to define one point on the unit circle. I then define a shorthand notation cp to compute the cross product. The inner cross products express join operations, the outer a meet. Then I rename my points and write down the condition for six points to lie on a conic, expressed as a polynomial in $3\times3$ determinants. (For details on this characterization, I suggest reading Perspectives on Projective Geometry by Richter-Gebert.) The result is 0, indicating that the points are indeed on a common conic. Unless some of the points are not defined due to degenerate input, of course.

For the second setup, the computation is almost the same, except for a change of indices (corresponding to your primes) in this part:

A3 = cp(cp(P, A1), cp(B1, C1))
B3 = cp(cp(P, B1), cp(C1, A1))
C3 = cp(cp(P, C1), cp(A1, B1))
A4 = cp(cp(P, A2), cp(B2, C2))
B4 = cp(cp(P, B2), cp(C2, A2))
C4 = cp(cp(P, C2), cp(A2, B2))

The result is still zero.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.