2
$\begingroup$

Show that the curve of intersection of the surfaces $x^2+2y^2-z^2+3x=1$ and $2x^2+4y^2-2z^2-5y=0$ lies in a plane.

I was able to do this by doubling both sides of the first equation and subtracting it from the second equation, ending up with $6x+5y=2$, which is the equation of a plane. I then used Mathematica to sketch the result.

ContourPlot3D[{x^2 + 2 y^2 - z^2 + 3 x == 1, 
  2 x^2 + 4 y^2 - 2 z^2 - 5 y == 0, 6 x + 5 y == 2},
 {x, -5, 3.2}, {y, -3, 3}, {z, -3, 3},
 ContourStyle -> Opacity[0.5],
 Mesh -> None,
 BoundaryStyle -> {{1, 2} -> {Thick, Red}},
 AxesLabel -> Automatic]

The resulting image:

enter image description here

Now, a couple of things:

  1. I found it surprising that when I solve the two equations using elimination, I did not get the equation of the curve of intersection, but rather the plane on which it lies. Any thoughts on this question?

  2. Note that I have highlighted the curve of intersection in red, and it lies on the plane $6x+5y=2$. Now, how can I go about finding the equation of that curve?

Update:

Thanks for the help. Here is my final work.

ans = Solve[6 x + 5 y == 2, x];
2 x^2 + 4 y^2 - 2 z^2 - 5 y == 0 /. First[ans] // Simplify

Which yielded: 4 + 97 y^2 == 110 y + 36 z^2. Then I completed the square and got:

$$\frac{(y-55/97)^2}{2637/9409}-\frac{z^2}{293/388}=1$$

Using the fact that $\cosh^2t-\sinh^2t=1$, I parametrized this in the yz-plane:

$$\begin{align*} x&=0\\ y&=\frac{55}{97}+\sqrt{\frac{2637}{9409}}\cosh t\\ z&=\sqrt{\frac{293}{388}}\sinh t \end{align*}$$

Pushing this toward the plane $6x+5y=2$, the y- and z-values do not change. Solving for x:

Solve[6 x + 5 y == 2 /. y -> 55/97 + Sqrt[2637/9409] Cosh[t], x]

Which yielded:

$$\begin{align*} x&=-\frac{27}{194}-\frac{5\sqrt{293}}{194}\cosh t\\ y&=\frac{55}{97}+\sqrt{\frac{2637}{9409}}\cosh t\\ z&=\sqrt{\frac{293}{388}}\sinh t \end{align*}$$

My final code:

Show[ContourPlot3D[{x^2 + 2 y^2 - z^2 + 3 x == 1, 
   2 x^2 + 4 y^2 - 2 z^2 - 5 y == 0},
  {x, -5, 3.2}, {y, -3, 3}, {z, -3, 3},
  ContourStyle -> Opacity[0.5],
  Mesh -> None,
  AxesLabel -> Automatic],
 ParametricPlot3D[{-27/194 - (5 Sqrt[293])/194 Cosh[t], 
   55/97 + Sqrt[2637/9409] Cosh[t], Sqrt[293/388] Sinh[t]}, {t, -3, 3},
  PlotStyle -> {Thick, Red}],
 ViewPoint -> {-0.5, 3, 1.5}
 ]

Which yielded this image.

enter image description here

Similar work yield the curve of intersection on the other side.

Show[ContourPlot3D[{x^2 + 2 y^2 - z^2 + 3 x == 1, 
   2 x^2 + 4 y^2 - 2 z^2 - 5 y == 0},
  {x, -5, 3.2}, {y, -3, 3}, {z, -3, 3},
  ContourStyle -> Opacity[0.5],
  Mesh -> None,
  AxesLabel -> Automatic],
 ParametricPlot3D[{
   {-27/194 - (5 Sqrt[293])/194 Cosh[t], 
    55/97 + Sqrt[2637/9409] Cosh[t], Sqrt[293/388] Sinh[t]},
   {-27/194 + (5 Sqrt[293])/194 Cosh[t], 
    55/97 - Sqrt[2637/9409] Cosh[t], Sqrt[293/388] Sinh[t]}
   }, {t, -3, 3},
  PlotStyle -> Directive[Thick, Red]],
 ViewPoint -> {-0.5, 3, 1.5}
 ]

enter image description here

$\endgroup$

2 Answers 2

3
$\begingroup$

The reason you only obtained the plane after step 1 is because you have only carried out one step in the solution of the system of 2 equations. Since your system has more variables than equations, you will need to proceed further using the results from your first step.

For example, substituting the plane $y=\frac{2-6x}{5}$ inside either of the equations gives an expression involving $z$ and $y$.

$\endgroup$
2
$\begingroup$

The answers to your questions are related: what you have done by subtracting the equations is create another equation that must be satisfied by the points in the intersection. This equation is not equivalent to the two equations you began with, but having one of the initial equations as well as the new equation is sufficient to determine the intersection.

Which brings us to your next question: you have to solve $6x+5y=2$ and one of the other equations simultaneously, which will give you an expression in terms of two of the variables. Actually, it's not possible to express the curve using only one equation: because it is three-dimensional, and each equation produces something that (normally) looks like a surface, you can only create a line by having two equations be satisfied simultaneously.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.